|   Home   |   Excel   |   Access   |   Word   |   Outlook   |   VBA   |   eBooks   |   Handouts   |   Site Index   |

 Calculating Age in Excel...

# Working Out a Person's Age in Excel

Published: 19 July 2001
Revised: 29 April 2013
Author: Martin Green
Screenshots: Excel 2010, Windows 7
For Excel Versions: All

## How Excel Works with Dates

Excel considers dates as numbers. Each date is assigned a unique serial number. For example, the 27th September 1999 was date serial 36430. Fortunately, you don't need to know this but the fact that all dates have numerical values can be very useful. Windows uses the 1900 date system in which 1st January 1900 is date serial 1, 2nd January 1900 is date serial 2 and so on.

When you type a date into a cell, Excel shows you a date but is thinking of a number. To find out the serial number of a date, select the cell containing the date then open the Format Cells dialog by (in Excel 2007 and later) expanding the Number section of the Home tab (click the arrow in the lower right corner) or (in Excel 2003 and earlier) opening the Format menu and choosing Cells. Go to the Number tab and click General in the Category list. The date's serial number will appear in the Sample box on the right.

You can make use of these numbers in all sorts of ways. You can add a number to a date to give a date that is a number of days later, or subtract a number to get a date before. You can take one date from another to find out how many days in between. There are lots of ready-made date functions too.

## Working Out a Person's Age

A person's age is the amount of time since they were born (I know you know that but the computer doesn't, and we have to start thinking like the computer). So, all we have to do is put today's date in one cell and the person's date of birth in another cell, then take their date of birth away from today and you get their age - right? Well, sort of... you get a number. Because you took a date serial from another date serial you get the number of days in between (see NOTE below). It looks like this...

In this example the formula in cell A3 is =A1-A2

NOTE: In older versions of Excel you might get another date. Confused? Don't be. Excel is trying to help but has misunderstood what we need. In date calculations, the result cell gets automatically formatted the same way as the first cell in the formula. Because the first cell was formatted as a date Excel showed you the result as a date, although you wanted to see a number. Just reformat the cell manually by (in Excel 2003 and older) going to Format > Cells > General or (in Excel 2007 and later) choosing General from the dropdown in the Format section of the Home tab.

We need to convert this number of days into a number of years. Most years have 365 days but every fourth year has 366 days. So the average number of years is 365.25. Let's modify our formula...

In this example the formula in cell A3 is =(A1-A2)/365.25

Note the brackets around the first part of the formula. Brackets mean "Work out this bit first...". I've used them here to stop Excel trying to divide A2 by 365.25 before taking it away from A1. Excel formulas do any multiplying and dividing before doing any adding and subtracting, but anything in brackets gets done first.

Now we can see a number of years, but it's still not quite right. We are getting an accurate result but we don't really want to see the fraction. As a last refinement we'll wrap the whole thing inside an INT() function to give us a whole number (an integer). This is better than changing the number of decimal places displayed, which would risk some numbers being rounded up and giving an incorrect result. Here's the finished result...

In this example the formula in cell A3 is =INT((A1-A2)/365.25)

## Inserting Today's Date Automatically

You can save yourself the effort of entering today's date manually. Excel has a function TODAY() that creates the current date. All you need to do is place this function into the age calculation formula in place of the reference of the cell that had today's date in it...

In this example the formula in cell A3 is =INT((TODAY()-A2)/365.25)

## How Accurate Do You Need to Be?

This formula yields pretty accurate results but it isn't infallible. Dividing by the average number of days in a year works for most people most of the time, but sometimes it gets it wrong. Supposing the person in question is a child, who hasn't yet lived through a 366 day year, you should be dividing by 365 and not 365.25. Also, because the way this formula calculates, if a person was born in a leap year and today is their birthday it doesn't get their age right until tomorrow. When I updated this tutorial I ran a check again and came up with 29 such errors out of a total of 41,393 possible dates since 1 January 1900.

But if you are going to do it, you might as well do it right! So how can we get an exact, guaranteed correct figure? Read on...

## Using Nested IF Statements to Tell It Like It Is!

Supposing it's August and you need to know old someone is...

• The person was born in 1975. How old are they? You can't say.
• The person was born in August 1975. How old are they? You still can't say.
• The person was born on 23rd August 1975. How old are they? At last! You have enough information. You can say for certain.

In order to calculate someone's age precisely you need to know the year in which they were born and whether or not they have had their birthday. If they have had their birthday you subtract their birth year from the current year. If they have not yet had their birthday you subtract their birth year from the current year, and then subtract 1. Easy! We do it all the time without thinking about it. But explaining the rules to Excel is a bit more complicated. Here goes...

=IF(MONTH(TODAY())>MONTH(A1),YEAR(TODAY())-YEAR(A1),
IF(AND(MONTH(TODAY())=MONTH(A1),DAY(TODAY())>=DAY(A1)),
YEAR(TODAY())-YEAR(A1),(YEAR(TODAY())-YEAR(A1))-1))

I've written this calculation on three lines for clarity but you should write is as a single expression without spaces. It assumes that cell A1 contains the person's date of birth. Here's what it says...

IF(MONTH(TODAY())>MONTH(A1)
If this month is later than the month of the persons birthday...

YEAR(TODAY())-YEAR(A1)
...subtract the year in which they were born from this year because they must have had their birthday.

But what if we haven't passed the month in which they were born. We might be in that month, or we might not have reached it yet. Let's find out...

IF(AND(MONTH(TODAY())=MONTH(A1),DAY(TODAY())>=DAY(A1))
If we are currently in the month of the person's birthday and it is either their birthday today or we have passed it...

YEAR(TODAY())-YEAR(A1)
...subtract the year in which they were born from this year because they must have had their birthday.

But what if this isn't the month in which they were born. We know we haven't passed their birthday so...

(YEAR(TODAY())-YEAR(A1))-1
...subtract the year in which they were born from this year then subtract 1, because they haven't had their birthday yet.

Phew!

## But What About the DATEDIF() Function?

Ah yes! Those in the know will tell you that you don't need all this messing about with IFs because Microsoft has provided the DATEFIF() function. That's perfectly true but note that I said "those in the know". The DATEDIF() function will accurately determine the number of specified time intervals between two given dates. There is an excellent explanation of it on Chip Pearson's web site here: http://www.cpearson.com/excel/datedif.aspx  But, whilst it is works in Excel, Microsoft has seen fit not to support it in any version since Excel 2000. You won't find it mentioned in Help or listed in the Insert Function tool. If there is a reason for that Microsoft isn't saying, although it seems to work perfectly for me, but I prefer to play safe. And anyway, if you've read this far, you've at least learned something about nested IFs.

An IF function contains three arguments:

IF(Logical Test,Value If True,Value If False)

Logical Test: This is a question or circumstance than can be answered yes or no, or true or false.

Value If True: This is what the function should do if the answer to the test is yes or true.

Value If False: This is what the function should do if the answer to the test is no or false.

In other words, you ask a question. If the answer is yes you do one thing. If the answer is no you do something else. What the IF function does could be to display a number or piece of text, or it can do a calculation (which is what is does in the example I've used here).

But what if you don't have a simple yes/no question. The solution is a nested IF function. Instead of inserting a number, piece of text or calculation, the value if true or value if false part (or both parts) can be IF functions themselves. They normally need a bit of working out (!) because they have to use the same logical process as Excel does. If it doesn't work first time, try writing it a different way. And try "translating" it into English as I did above.

A nested IF function says something like...

"If the answer is yes, do this. If the answer is no do this or this (depending on..."

And if you think the Age Calculator is complicated, consider the fact that from version 2007 on Excel can handle up to forty-seven (count them!) nested IF functions in a single calculation (older versions could only manage a mere seven!).

^ top